// Set properties before any plugins get loaded
project.ext {
  // Execute tests on all JVMs, even rare and outdated ones
  coreJavaInstrumentation = true
}

apply from: "${rootDir}/gradle/java.gradle"
apply from: "${rootDir}/gradle/test-with-scala.gradle"

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  slickTest
}

compileSlickTestGroovy {
  classpath = classpath.plus(files(compileSlickTestScala.destinationDir))
  dependsOn compileSlickTestScala
}

dependencies {
  compile project(':dd-trace-api')
  compile project(':dd-java-agent:agent-tooling')

  compile deps.bytebuddy
  compile deps.opentracing
  annotationProcessor deps.autoservice
  implementation deps.autoservice

  testCompile project(':dd-java-agent:testing')
  testCompile project(':dd-java-agent:instrumentation:trace-annotation')

  slickTestCompile project(':dd-java-agent:testing')
  slickTestCompile project(':dd-java-agent:instrumentation:java-concurrent')
  slickTestCompile project(':dd-java-agent:instrumentation:trace-annotation')
  slickTestCompile project(':dd-java-agent:instrumentation:jdbc')
  slickTestCompile group: 'org.scala-lang', name: 'scala-library', version: '2.11.12'
  slickTestCompile group: 'com.typesafe.slick', name: 'slick_2.11', version: '3.2.0'
  slickTestCompile group: 'com.h2database', name: 'h2', version: '1.4.197'
}

// Run Slick library tests along with the rest of unit tests
test.dependsOn slickTest