// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

muzzle {
  pass {
    group = "org.elasticsearch.client"
    module = "rest"
    versions = "[5.0,6.4)"
    assertInverse = true
  }

  pass {
    group = "org.elasticsearch.client"
    module = "elasticsearch-rest-client"
    versions = "[5.0,6.4)"
  }
}

apply from: "${rootDir}/gradle/java.gradle"

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest
}

dependencies {
  compileOnly group: 'org.elasticsearch.client', name: 'rest', version: '5.0.0'

  compile project(':dd-java-agent:agent-tooling')

  compile deps.bytebuddy
  compile deps.opentracing
  annotationProcessor deps.autoservice
  implementation deps.autoservice

  testCompile project(':dd-java-agent:testing')
  // Include httpclient instrumentation for testing because it is a dependency for elasticsearch-rest-client.
  // It doesn't actually work though.  They use HttpAsyncClient, which isn't currently instrumented.
  // TODO: add Apache's HttpAsyncClient instrumentation when that is complete.
  testCompile project(':dd-java-agent:instrumentation:apache-httpclient-4')

  testCompile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.11.0'
  testCompile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.11.0'

  testCompile group: 'org.elasticsearch.client', name: 'rest', version: '5.0.0'
  testCompile group: 'org.elasticsearch', name: 'elasticsearch', version: '5.0.0'
  testCompile group: 'org.elasticsearch.plugin', name: 'transport-netty3-client', version: '5.0.0'

  latestDepTestCompile group: 'org.elasticsearch.client', name: 'elasticsearch-rest-client', version: '6.3.+'
  latestDepTestCompile group: 'org.elasticsearch', name: 'elasticsearch', version: '6.3.+'
  latestDepTestCompile group: 'org.elasticsearch.plugin', name: 'transport-netty4-client', version: '6.3.+'
}

configurations.latestDepTestCompile {
  exclude group: "org.elasticsearch.client", module: "rest"
}