// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

apply from: "${rootDir}/gradle/java.gradle"

muzzle {
  pass {
    group = "io.netty"
    module = "netty-codec-http"
    versions = "[4.1.0.Final,)"
    assertInverse = true
  }
  pass {
    group = "io.netty"
    module = "netty"
    versions = "[4.1.0.Final,)"
    assertInverse = true
  }
  pass {
    group = "io.vertx"
    module = "vertx-core"
    versions = "[3.3.0,)"
    assertInverse = true
  }
}

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

dependencies {
  compileOnly group: 'io.netty', name: 'netty-codec-http', version: '4.1.0.Final'

  testCompile project(':dd-java-agent:instrumentation:java-concurrent')
  testCompile group: 'io.netty', name: 'netty-codec-http', version: '4.1.0.Final'
  testCompile group: 'org.asynchttpclient', name: 'async-http-client', version: '2.1.0'

  latestDepTestCompile group: 'io.netty', name: 'netty-codec-http', version: '(,5.0)'
  // latest async-http-client incompatable with 5.0+ netty
  latestDepTestCompile group: 'org.asynchttpclient', name: 'async-http-client', version: '+'
}

// We need to force the dependency to the earliest supported version because other libraries declare newer versions.
configurations.testCompile {
  resolutionStrategy {
    eachDependency { DependencyResolveDetails details ->
      //specifying a fixed version for all libraries with io.netty' group
      if (details.requested.group == 'io.netty') {
        details.useVersion "4.1.0.Final"
      }
    }
  }
}