apply from: "${rootDir}/gradle/java.gradle"

minimumBranchCoverage = 0.6
minimumInstructionCoverage = 0.8
excludedClassesCoverage += [
  'io.opentelemetry.auto.tooling.*',
  'io.opentelemetry.auto.decorator.*' // temporarily until all the deprecated methods which are no longer being tested are removed
]

configurations {
  // classpath used by the instrumentation muzzle plugin
  instrumentationMuzzle
}

dependencies {
  compile(project(':auto-bootstrap')) {
    // This only needs to exist in the bootstrap, not the instrumentation jar.
    exclude group: 'org.slf4j', module: 'slf4j-simple'
  }
  compile(project(':utils:thread-utils'))

  compile deps.opentelemetryApi
  compile deps.opentelemetrySdk

  // TODO: This might have to live in opentelemetry-java
  compile project(':exporter-support')

  compile group: 'com.blogspot.mydailyjava', name: 'weak-lock-free', version: '0.15'
  compile deps.bytebuddy
  compile deps.bytebuddyagent
  annotationProcessor deps.autoservice
  implementation deps.autoservice

  testCompile project(':testing')

  instrumentationMuzzle sourceSets.main.output
  instrumentationMuzzle configurations.compile
}