plugins {
  id "java"
  id "com.google.cloud.tools.jib" version "2.6.0"
}

group = "io.opentelemetry"
version = "0.0.1-SNAPSHOT"

repositories {
  mavenCentral()
  jcenter()
  // this is only needed for the working against unreleased otel-java snapshots
  maven {
    url "https://oss.sonatype.org/content/repositories/snapshots"
    content {
      includeGroup "io.opentelemetry"
    }
  }
}

dependencies {
  implementation platform("io.grpc:grpc-bom:1.33.1")
  implementation platform("io.opentelemetry:opentelemetry-bom:1.0.0")
  implementation platform("io.opentelemetry:opentelemetry-bom-alpha:1.0.0-alpha")
  implementation platform("org.apache.logging.log4j:log4j-bom:2.13.2")

  implementation "io.grpc:grpc-netty-shaded"
  implementation "io.grpc:grpc-protobuf"
  implementation "io.grpc:grpc-stub"
  implementation "io.opentelemetry:opentelemetry-proto"
  implementation "io.opentelemetry:opentelemetry-extension-annotations"
  implementation "org.apache.logging.log4j:log4j-core"

  runtimeOnly("org.apache.logging.log4j:log4j-slf4j-impl")
}

compileJava {
  options.release = 8
}

def targetJDK = project.hasProperty("targetJDK") ? project.targetJDK : 11

def tag = findProperty("tag") ?: new Date().format("yyyyMMdd.HHmmSS")

jib {
  from.image = "bellsoft/liberica-openjdk-alpine:$targetJDK"
  to.image = "ghcr.io/open-telemetry/java-test-containers:smoke-grpc-jdk$targetJDK-$tag"
}