muzzle {
  pass {
    group = "org.eclipse.jetty"
    module = 'jetty-server'
    versions = "[8.0.0.v20110901,)"
    assertInverse = true
  }
}

apply from: "${rootDir}/gradle/java.gradle"

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

dependencies {
  compileOnly group: 'org.eclipse.jetty', name: 'jetty-server', version: '8.0.0.v20110901'

  // Don't want to conflict with jetty from the test server.
  testCompile(project(':dd-java-agent:testing')) {
    exclude group: 'org.eclipse.jetty', module: 'jetty-server'
  }
  testCompile project(':dd-java-agent:instrumentation:java-concurrent')

  testCompile group: 'org.eclipse.jetty', name: 'jetty-server', version: '8.0.0.v20110901'
  testCompile group: 'org.eclipse.jetty', name: 'jetty-servlet', version: '8.0.0.v20110901'
  testCompile group: 'org.eclipse.jetty', name: 'jetty-continuation', version: '8.0.0.v20110901'

  // Jetty 10 seems to refuse to run on java8.
  // TODO: we need to setup separate test for Jetty 10 when that is released.
  latestDepTestCompile group: 'org.eclipse.jetty', name: 'jetty-server', version: '9.+'
  latestDepTestCompile group: 'org.eclipse.jetty', name: 'jetty-servlet', version: '9.+'
  latestDepTestCompile group: 'org.eclipse.jetty', name: 'jetty-continuation', version: '9.+'
}