// Set properties before any plugins get loaded
ext {
  minJavaVersionForTests = JavaVersion.VERSION_1_8
}

apply from: "$rootDir/gradle/instrumentation.gradle"
apply plugin: 'org.unbroken-dome.test-sets'

muzzle {
  pass {
    group = "org.elasticsearch.client"
    module = "transport"
    versions = "[5.3.0,6.0.0)"
    assertInverse = true
  }
  pass {
    group = "org.elasticsearch"
    module = "elasticsearch"
    versions = "[5.3.0,6.0.0)"
    assertInverse = true
  }
}

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

dependencies {
  compileOnly group: 'org.elasticsearch.client', name: 'transport', version: '5.3.0'

  implementation project(':instrumentation:elasticsearch:elasticsearch-transport-common')

  testImplementation project(':instrumentation:apache-httpasyncclient-4.0')
  testImplementation project(':instrumentation:netty:netty-4.1')
  testImplementation project(':instrumentation:spring-data-1.8')

  testImplementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.11.0'
  testImplementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.11.0'

  testImplementation group: 'org.elasticsearch.plugin', name: 'transport-netty3-client', version: '5.3.0'
  testImplementation group: 'org.elasticsearch.client', name: 'transport', version: '5.3.0'

  // Unfortunately this will bump the transport version up to 5.5.0.
  testImplementation group: 'org.springframework.data', name: 'spring-data-elasticsearch', version: '3.0.0.RELEASE'

  latestDepTestImplementation group: 'org.elasticsearch.plugin', name: 'transport-netty3-client', version: '5.+'
  latestDepTestImplementation group: 'org.elasticsearch.client', name: 'transport', version: '5.+'
  latestDepTestImplementation group: 'org.springframework.data', name: 'spring-data-elasticsearch', version: '3.0.+'
}