// Set properties before any plugins get loaded
project.ext {
  // Execute tests on all JVMs, even rare and outdated ones
  coreJavaInstrumentation = true
  minJavaVersionForTests = JavaVersion.VERSION_1_7
}

muzzle {
  pass {
    group = "org.hibernate"
    module = "hibernate-core"
    versions = "[4.0.0.Final,)"
    assertInverse = true
  }
}

apply from: "${rootDir}/gradle/java.gradle"

apply plugin: 'org.unbroken-dome.test-sets'

testSets {
  latestDepTest {
    dirName = 'test'
  }
}

dependencies {
  compileOnly group: 'org.hibernate', name: 'hibernate-core', version: '4.0.0.Final'

  compile project(':dd-java-agent:agent-tooling')
  compile project(':dd-java-agent:instrumentation:hibernate')

  compile deps.bytebuddy
  compile deps.opentracing
  annotationProcessor deps.autoservice
  implementation deps.autoservice

  testCompile project(':dd-java-agent:testing')
  testCompile project(':dd-java-agent:instrumentation:jdbc')
  // Added to ensure cross compatibility:
  testCompile project(':dd-java-agent:instrumentation:hibernate:core-3.3')
  testCompile project(':dd-java-agent:instrumentation:hibernate:core-4.3')

  testCompile group: 'org.hibernate', name: 'hibernate-core', version: '4.0.0.Final'
  testCompile group: 'com.h2database', name: 'h2', version: '1.4.197'
  testCompile "javax.xml.bind:jaxb-api:2.2.11"
  testCompile "com.sun.xml.bind:jaxb-core:2.2.11"
  testCompile "com.sun.xml.bind:jaxb-impl:2.2.11"
  testCompile "javax.activation:activation:1.1.1"

  latestDepTestCompile group: 'org.hibernate', name: 'hibernate-core', version: '4.2.+'
  latestDepTestCompile group: 'com.h2database', name: 'h2', version: '1.4.197'
  // Test that the incremental instrumentation for hibernate 4.3 doesn't cause issues.
  latestDepTestCompile project(':dd-java-agent:instrumentation:hibernate:core-4.3')
}