Migrate last test sets to test suites. (#4103)

* Migrate last test sets to test suites.

* Disable javadoc for tests project

integration-tests/build.gradle.kts

@@ -1,60 +1,16 @@
 plugins {
   id("otel.java-conventions")
-
-  id("org.unbroken-dome.test-sets")
 }
 
 description = "OpenTelemetry Integration Tests"
 otelJava.moduleName.set("io.opentelemetry.integration.tests")
 
-testSets {
-  libraries {
-    create("testOtlpCommon")
-  }
-
-  create("testOtlp") {
-    imports("testOtlpCommon")
-  }
-
-  create("testOtlpNoGrpcJava") {
-    imports("testOtlpCommon")
-  }
-}
-
 dependencies {
   testImplementation(project(":sdk:all"))
   testImplementation(project(":sdk:testing"))
   testImplementation(project(":extensions:trace-propagators"))
 
-  testImplementation("com.google.protobuf:protobuf-java")
   testImplementation("com.linecorp.armeria:armeria-junit5")
-  testImplementation("com.fasterxml.jackson.core:jackson-databind")
-  testImplementation("com.squareup.okhttp3:okhttp")
   testImplementation("org.junit.jupiter:junit-jupiter-params")
   testImplementation("org.testcontainers:junit-jupiter")
-  testImplementation("org.slf4j:slf4j-simple")
-
-  add("testOtlpCommonImplementation", project(":exporters:otlp:trace"))
-  add("testOtlpCommonImplementation", project(":exporters:otlp:metrics"))
-  add("testOtlpCommonImplementation", project(":exporters:otlp:logs"))
-  add("testOtlpCommonImplementation", project(":exporters:otlp-http:logs"))
-  add("testOtlpCommonImplementation", project(":exporters:otlp-http:metrics"))
-  add("testOtlpCommonImplementation", project(":exporters:otlp-http:trace"))
-  add("testOtlpCommonImplementation", project(":semconv"))
-  add("testOtlpCommonImplementation", "com.linecorp.armeria:armeria-grpc-protocol")
-  add("testOtlpCommonImplementation", "com.linecorp.armeria:armeria-junit5")
-  add("testOtlpCommonImplementation", "io.opentelemetry.proto:opentelemetry-proto")
-  add("testOtlpCommonImplementation", "org.assertj:assertj-core")
-  add("testOtlpCommonImplementation", "org.awaitility:awaitility")
-  add("testOtlpCommonImplementation", "org.junit.jupiter:junit-jupiter-params")
-  add("testOtlpCommonImplementation", "org.testcontainers:junit-jupiter")
-
-  add("testOtlpRuntimeOnly", "io.grpc:grpc-netty-shaded")
-  add("testOtlpRuntimeOnly", "io.grpc:grpc-stub")
-}
-
-tasks {
-  check {
-    dependsOn("testOtlp", "testOtlpNoGrpcJava")
-  }
 }

integration-tests/otlp/build.gradle.kts

@@ -0,0 +1,47 @@
+plugins {
+  id("otel.java-conventions")
+}
+
+description = "OTLP Exporter Integration Tests"
+otelJava.moduleName.set("io.opentelemetry.integration.tests.otlp")
+
+dependencies {
+  api("org.testcontainers:junit-jupiter")
+
+  implementation(project(":exporters:otlp:trace"))
+  implementation(project(":exporters:otlp:metrics"))
+  implementation(project(":exporters:otlp:logs"))
+  implementation(project(":exporters:otlp-http:logs"))
+  implementation(project(":exporters:otlp-http:metrics"))
+  implementation(project(":exporters:otlp-http:trace"))
+  implementation(project(":semconv"))
+
+  implementation("com.linecorp.armeria:armeria-grpc-protocol")
+  implementation("com.linecorp.armeria:armeria-junit5")
+  implementation("io.opentelemetry.proto:opentelemetry-proto")
+  implementation("org.assertj:assertj-core")
+  implementation("org.awaitility:awaitility")
+  implementation("org.junit.jupiter:junit-jupiter-params")
+}
+
+testing {
+  suites {
+    val testGrpcJava by registering(JvmTestSuite::class) {
+      dependencies {
+        runtimeOnly("io.grpc:grpc-netty-shaded")
+        runtimeOnly("io.grpc:grpc-stub")
+      }
+    }
+  }
+}
+
+tasks {
+  // Don't need javadoc.
+  javadoc {
+    isEnabled = false
+  }
+
+  check {
+    dependsOn(testing.suites)
+  }
+}

settings.gradle.kts

@@ -7,7 +7,6 @@ pluginManagement {
     id("io.github.gradle-nexus.publish-plugin") version "1.1.0"
     id("nebula.release") version "16.0.0"
     id("org.jetbrains.kotlin.jvm") version "1.6.10"
-    id("org.unbroken-dome.test-sets") version "4.0.0"
   }
 }
 
@@ -53,6 +52,7 @@ include(":exporters:otlp-http:trace")
 include(":exporters:prometheus")
 include(":exporters:zipkin")
 include(":integration-tests")
+include(":integration-tests:otlp")
 include(":integration-tests:tracecontext")
 include(":opencensus-shim")
 include(":opentracing-shim")